@*** Visokofrekvencni vir ADF4351+HMC273 - S53MV 22.03.2017 ***

@*** Konstante mikrokrmilnika LPC2138/01 ***
.equ	KVARC,14745600		@frekvenca kristala (Hz)
.equ	CLK,KVARC*4		@frekvenca jedra ARM (PLL)
.equ	PCLK,CLK/2		@frekvenca vhodno/izhodnih enot (APBDIV)
.equ	BAUD,PCLK/153600	@modulo deljenja UART za 9600bps*16
.equ	N1US,CLK/3000000	@konstanta cakanja T1US za HD44780

@*** Vhodno/izhodni prikljucki LPC2138/01 ***
@/RESET - vhod vezan na /ERROR.LP2951 in na /DTR.FT231XS
@P0.0/TXD0/PWM1 - izhod vezan na RXD.FT231XS 
@P0.1/RXD0/PWM3/EINT0 - vhod vezan na TXD.FT231XS
@P0.2.od/SCL0/CAP0.0 -
@P0.3.od/SDA0/MAT0.0/EINT1 -
@P0.4/SCK0/CAP0.1/AD0.6 - izhod slabilec HMC273 1dB
@P0.5/MISO0/MAT0.1/AD0.7 - izhod slabilec HMC273 2dB
@P0.6/MOSI0/CAP0.2/AD1.0 - izhod slabilec HMC273 4dB
@P0.7/SSEL0/PWM2/EINT2 - izhod slabilec HMC273 8dB
@P0.8/TXD1/PWM4/AD1.1 - izhod slabilec HMC273 16dB
@P0.9/RXD1/PWM6/EINT3 - izhod ON/OFF ADF4351 PDB
@P0.10/RTS1/CAP1.0/AD1.2 - izhod ADF4351 CLK
@P0.11.od/CTS1/CAP1.1/SCL1 - vhod ADF4351 MOXOUT
@P0.12/DSR1/MAT1.0/AD1.3 - izhod ADF4351 LE
@P0.13/DTR1/MAT1.1/AD1.4 - izhod ADF4351 DATA
@P0.14.od/DCD1/EINT1/SDA1/BOOTLOADER(!) - vhod vezan na /RTS.FT231XS 
@P0.15/RI1/EINT2/AD1.5 -
@P0.16-23 - digitalni izhodi za LCD D0-7.HD44780
@P0.24 - ne obstaja ***
@P0.25/AD0.4/AOUT -
@P0.26/AD0.5 -
@P0.27/AD0.0/CAP0.1/MAT0.1 -
@P0.28/AD0.1/CAP0.2/MAT0.2 -
@P0.29/AD0.2/CAP0.3/MAT0.3 -
@P0.30/AD0.3/EINT3/CAP0.0 -
@P0.31(!) - nepovezan ***
@P1.0-15 - ne obstajajo ***
@P1.16 - pull-up vhod - tipka DESNO
@P1.17 - pull-up vhod - tipka DOL
@P1.18 - pull-up vhod - tipka GOR
@P1.19 - pull-up vhod - tipka LEVO
@P1.20(!) - nepovezan ***
@P1.21 - digitalni izhod za LCD RS.HD44780
@P1.22-25 - nepovezani ***
@P1.26(!) - nepovezan ***
@P1.27-29 - nepovezani ***
@P1.30 - digitalni izhod za LCD E.HD44780
@P1.31 - nepovezan ***

@*** Dodelitev pomnilnika RAM ***
.equ	SKLAD,0x40000100	@sklad raste navzdol -256byte

.equ	ZASLON,0x40000180	@vsebina zaslona (32byte)

.equ	ZMIGA,0x40		@perioda utripanja (mora biti 2^N)

.equ	ZNACKA,0x40000200	@znacka na zaslonu
.equ	UTRIP,0x40000204	@stevec utripanja
.equ	KAZALO,0x40000208	@kazalec na velicino
.equ	TIPKES,0x4000020C	@stare tipke
.equ	PREMIK,0x40000210	@premik parametra
.equ	SPOMIN,0x40000214	@stevilka spomina nastavitve

.equ	POMNIL,0x40000300	@pomnilnik nastavitev (10*4*32bit)

@*** Ukazi za delovanje zbirnika Gnu ***
.text
.arm

@*** Tabela izjem na zacetnem naslovu 0 ***
IZJEME:	B	ZACNI	@RESET
	B	IZJEME	@Undef
	B	IZJEME	@SWI
	B	IZJEME	@PAbt
	B	IZJEME	@DAbt
	NOP		@Reserved Vector
	B	IZJEME	@IRQ
	B	IZJEME	@FIQ

@*** Pocisti pomnilnik do nevarne lokacije 0x000001FC ***
.balign	512,0

@*** Inicializiraj MAM *** (R0-1)
MAM:	LDR	R0,=0xE01FC000	@MAMCR=0
	MOV	R1,#0
	STRB	R1,[R0]
	LDR	R0,=0xE01FC004	@MAMTIM=3
	MOV	R1,#3
	STRB	R1,[R0]
	LDR	R0,=0xE01FC000	@MAMCR=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Nastavi PCONP in APBDIV *** (R0-1)
PWRCLK:	LDR	R0,=0xE01FC0C4	@PCONP
	LDR	R1,=0x00000008	@UART0
	STR	R1,[R0]
	LDR	R0,=0xE01FC100	@APBDIV=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj PLL *** (R0-2)
PLL:	LDR	R0,=0xE01FC084	@PLLCFG=0x24 P=2,M-1=3
	MOV	R1,#0x23
	STRB	R1,[R0]
	LDR	R0,=0xE01FC080	@PLLCON=0x01 PLL-enable
	MOV	R1,#0x01
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	@PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
PLL1:	LDR	R0,=0xE01FC088	@PLLSTAT cakanje uklenitve
	LDR	R1,[R0]
	ANDS	R1,R1,#0x400
	BEQ	PLL1
	LDR	R0,=0xE01FC080	@PLLCON=0x03 PLL-enable&connect
	MOV	R1,#0x03
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	@PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj GPIO in DAC *** (R0-1)
GPIO:	LDR	R0,=0xE002C000	@PINSEL0 P0.0-1=UART0
	LDR	R1,=0x00000005
	STR	R1,[R0]
	LDR	R0,=0xE002C004	@PINSEL1 P0.25=AOUT
	LDR	R1,=0x00080000
	STR	R1,[R0]
	LDR	R0,=0xE002C014	@PINSEL2 izklop JTAG&TRACE
	LDR	R1,[R0]
	BIC	R1,R1,#0x0C
	STR	R1,[R0]
	LDR	R0,=0xE01FC1A0	@SCS=0x03 high-speed GPIO 0&1
	MOV	R1,#0x03
	STR	R1,[R0]
	LDR	R0,=0x3FFFC014	@FIO0PIN vsi 1
	MOV	R1,#-1
	STR	R1,[R0]
	LDR	R0,=0x3FFFC034	@FIO1PIN vsi 0
	MOV	R1,#0
	STR	R1,[R0]
	LDR	R0,=0x3FFFC000	@FIO0DIR izhodi 0.0-0.10, 0.12-0.13, 0.15-0.31
	LDR	R1,=0xFFFFB7FF
	STR	R1,[R0]
	LDR	R0,=0x3FFFC020	@FIO1DIR izhodi 1.20-1.31
	LDR	R1,=0xFFF00000
	STR	R1,[R0]
	LDR	R0,=0xE006C000	@DACR sredina skale, visok tok
	LDR	R1,=0x00008000
	STR	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj UART0 *** (R0-1)
UART0:	LDR	R0,=0xE000C00C	@U0LCR=0x83 DLAB=1,no-parity,1stop,8bit
	MOV	R1,#0x83
	STRB	R1,[R0]
	LDR	R0,=0xE000C000	@U0DLL 
	LDR	R1,=BAUD
	STRB	R1,[R0]
	LDR	R0,=0xE000C004	@U0DLM
	MOV	R1,R1,LSR#8
	STRB	R1,[R0]
	LDR	R0,=0xE000C008	@U0FCR=0xC1 RXtrig=14bit,FIFOenable
	MOV	R1,#0xC1
	STRB	R1,[R0]
	LDR	R0,=0xE000C00C	@U0LCR=0x03 DLAB=0,no-parity,1stop,8bit
	MOV	R1,#0x03
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj HD44780 5X7,2vrstici,CGRAM *** (R0-3)
INILCD:	STR	LR,[SP,#-4]!	@resi link
	BL	T100MS		@zakasnitev 100ms
	MOV	R0,#0x38	@function set 
	BL	UKAZ
	BL	T4MS		@zakasnitev 4ms
	MOV	R0,#0x38	@function set
	BL	UKAZ
	MOV	R0,#0x38	@function set
	BL	UKAZ
	MOV	R0,#0x08	@display off
	BL	UKAZ
	MOV	R0,#0x01	@display clear
	BL	UKAZ
	BL	T4MS		@zakasnitev 4ms
	MOV	R0,#0x06	@entry mode set
	BL	UKAZ
	MOV	R0,#0x0C	@display on
	BL	UKAZ
	MOV	R0,#0x40	@set CGRAM address
	BL	UKAZ
	MOV	R2,#64		@prepisi 8 znake = 64 bajtov @@@@@@@@@@@@@@@@@@@@
	LDR	R3,=INILCD2
INILCD1:
	LDRB	R0,[R3],#1
	BL	ZNAK
	SUBS	R2,R2,#1
	BNE	INILCD1
	MOV	R0,#0x80	@set DDRAM address zacetek prve vrstice
	BL	UKAZ
	LDR	PC,[SP],#4	@povratek na link
.ltorg
INILCD2:
.byte	0x15,0x0A,0x15,0x0A,0x15,0x0A,0x15,0x00	@0=sahovnica
.byte	0x1F,0x0E,0x15,0x1B,0x15,0x0E,0x1F,0x00	@1=crnikriz
.byte	0x04,0x0E,0x1F,0x1F,0x1F,0x0E,0x04,0x00	@2=diamant
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
.byte	0x15,0x15,0x15,0x15,0x15,0x15,0x00,0x04	@3=tricrtice
.byte	0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x1F	@0=praznina podcrtana
.byte	0x10,0x10,0x10,0x10,0x10,0x10,0x00,0x1F	@1=enacrtica podcrtana
.byte	0x14,0x14,0x14,0x14,0x14,0x14,0x00,0x1F	@2=dvecrtici podcrtana
.byte	0x15,0x15,0x15,0x15,0x15,0x15,0x00,0x1F	@3=tricrtice podcrtana
.align

@*** Znak iz R0 v HD44780 *** (R0-1)
ZNAK:	STR	LR,[SP,#-4]!	@resi link
	LDR	R1,=0x3FFFC016	@FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03A	@FIO1SET2
	MOV	R0,#0x20	@RS=1
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03B	@FIO1SET3
	MOV	R0,#0x40	@vklopi E
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03F	@FIO1CLR3
	MOV	R0,#0x40	@izklopi E
	STRB	R0,[R1]
	BL	T100US		@zakasnitev 100us
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Ukaz iz R0 v HD44780 *** (R0-1)
UKAZ:	STR	LR,[SP,#-4]!	@resi link
	LDR	R1,=0x3FFFC016	@FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03E	@FIO1CLR2
	MOV	R0,#0x20	@RS=0
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03B	@FIO1SET3
	MOV	R0,#0x40	@vklopi E
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03F	@FIO1CLR3
	MOV	R0,#0x40	@izklopi E
	STRB	R0,[R1]
	BL	T100US		@zakasnitev 100us
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 1us *** (R0)
.balign	16,0
T1US:	MOV	R0,#N1US
T1US1:	SUBS	R0,R0,#1
	BPL	T1US1
	MOV	PC,LR

@*** Zakasnitev 100us *** (R0-1)
T100US:	STR	LR,[SP,#-4]!	@resi link
	MOV	R1,#100
T100US1:
	BL	T1US
	SUBS	R1,R1,#1
	BPL	T100US1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 4ms *** (R0-2)
T4MS:	STR	LR,[SP,#-4]!	@resi link
	MOV	R2,#40
T4MS1:	BL	T100US
	SUBS	R2,R2,#1
	BPL	T4MS1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 100ms *** (R0-3)
T100MS:	STR	LR,[SP,#-4]!	@resi link
	MOV	R3,#25
T100MS1:
	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T100MS1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 1s *** (R0-3)
T1S:	STR	LR,[SP,#-4]!	@resi link
	MOV	R3,#250
T1S1:	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T1S1
	LDR	PC,[SP],#4	@povratek na link

@*** Nepredznaceno deljenje R3/R0=R3, ostanek v R0 *** (R0-3)
NDELI:	MOVS	R1,R0		@prepreci deljenje z 0?
	MOVEQ	PC,LR
	MOV	R2,#1
	BMI	NDELI2
NDELI1:	MOV	R2,R2,LSL#1	@enica delitelja v MSB
	MOVS	R1,R1,LSL#1
	BPL	NDELI1
NDELI2:	MOV	R0,R3		@ostanek v R0
	MOV	R3,#0		@kvocient v R3
NDELI3:	CMP	R0,R1
	SUBCS	R0,R0,R1
	ADDCS	R3,R3,R2
	MOV	R1,R1,LSR#1
	MOVS	R2,R2,LSR#1
	BNE	NDELI3
	MOV	PC,LR

@*** Zacetek programa po resetu ***
ZACNI:	LDR	SP,=SKLAD	@inicializiraj SP
	BL	MAM	@inicializiraj MAM
	BL	PWRCLK	@nastavi PCONP in APBDIV
	BL	PLL	@inicializiraj PLL
	BL	GPIO	@inicializiraj GPIO in DAC
	BL	UART0	@inicializiraj UART0
	BL	INILCD	@inicializiraj HD44780 5X7,2vrstici,CGRAM
	MOV	R0,#0x80	@prva vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI5
ZACNI1:	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI2
	BL	ZNAK
	B	ZACNI1
ZACNI2:	MOV	R0,#0xC0	@druga vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI6
ZACNI3:	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI4
	BL	ZNAK
	B	ZACNI3
ZACNI4:	BL	T1S		@zakasnitev 1s
	MOV	R8,#31		@zacetni stevec zanke

	MOV	R0,#3		@zacetni SPOMIN
	LDR	R1,=SPOMIN
	STR	R0,[R1]

	B	ZANKA	@glavna zanka programa
.ltorg
ZACNI5:	.asciz	"VF izvor ADF4351"
ZACNI6:	.asciz	"S53MV 22.03.2017"
.align

@*** Glavna zanka programa ***
ZANKA:	LDR	R0,=0xE000C000	@U0THR izpis stevca na UART0
	STRB	R8,[R0]
	LDR	R0,=0xE006C000	@DACR zaga iz stevca, visok tok
	AND	R1,R8,#0xFF
	MOV	R1,R1,LSL#8
	STR	R1,[R0]

	TST	R8,#0xFF	@vsakih 256 zank
	BLEQ	INIADF		@postavi registre ADF4351

	MOV	R3,R8,LSR#3
	BL	SETHMC		@postavi slabilec HMC273 iz R3

	BL	TIPKE		@preberi ukaz s tipk
	BL	IZVEDI		@izvedi ukaz s tipk
	BL	MENU		@izpisi menu na zaslon
	BL	IZPIS		@izpisi vsebino pomnilnika 2x16 znakov

	BL	T4MS		@zakasnitev 4ms
	ADD	R8,R8,#1	@stevec zanke
	B	ZANKA
.ltorg

@*** Postavi slabilec HMC273 iz R3 *** (R0-3)
SETHMC:	MOV	R2,#0x01F0	@omejitev 5 bitov P0.4-8
	AND	R3,R2,R3,LSL#4
	LDR	R1,=0x3FFFC014	@FIO0PINL 16(half-word)
	LDRH	R0,[R1]
	BIC	R0,R0,R2
	ORR	R0,R0,R3
	STRH	R0,[R1]
	MOV	PC,LR
.ltorg

@*** Postavi registre ADF4351 *** (R0-3)
INIADF:	STR	LR,[SP,#-4]!	@resi link
	LDR	R3,=0x00580005	@register5: DLD
	BL	WADF
	LDR	R3,=0x00AFE03C	@register4: FUND, RF=/4, BSCD=240, VCO, RFOUT=+5dBm 
	BL	WADF
	LDR	R3,=0x00800003	@register3: BSCM=1
	BL	WADF
	LDR	R3,=0x78004E42	@register2: LSMODE, DLD, R=1, CPC=7, PDP=+
	BL	WADF
	LDR	R3,=0x0800FF41	@register1: 8/9, P=1, MOD=4000=0xFA0
	BL	WADF
	LDR	R3,=0x00322AA0	@register0: INT=100, FRAC=1365=0x555
	BL	WADF
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** 32-bitni ukaz iz R3 v ADF4351 *** (R0-3)
WADF:	STR	LR,[SP,#-4]!	@resi link
	MOV	R2,#32
WADF1:	ADDS	R3,R3,R3	@pomikalni register podatkov
	LDRCS	R0,=0x3FFFC019	@FIO0SET1
	LDRCC	R0,=0x3FFFC01D	@FIO0CLR1
	MOV	R1,#32		@P0.13=DATA
	STRB	R1,[R0]
	BL	T1US
	LDR	R0,=0x3FFFC019	@FIO0SET1 impulz CLK
	MOV	R1,#4		@P0.10=CLK
	STRB	R1,[R0]
	BL	T1US
	LDR	R0,=0x3FFFC01D	@FIO0CLR1
	MOV	R1,#4		@P0.10=CLK
	STRB	R1,[R0]
	SUBS	R2,R2,#1	@zanka 32 bitov
	BNE	WADF1
	BL	T1US
	LDR	R0,=0x3FFFC019	@FIO0SET1 impulz LE
	MOV	R1,#16		@P0.12=LE
	STRB	R1,[R0]
	BL	T1US
	LDR	R0,=0x3FFFC01D	@FIO0CLR1
	MOV	R1,#16		@P0.12=LE
	STRB	R1,[R0]
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Izpisi vsebino pomnilnika 2x16 znakov *** (R0,R1,R2,R3,R4)
IZPIS:	STR	LR,[SP,#-4]!	@resi link
	LDR	R3,=ZASLON
	LDR	R0,=ZNACKA	@utripajoca znacka
	LDR	R4,[R0]
	LDR	R0,=UTRIP
	LDR	R1,[R0]
	ADD	R1,R1,#1
	STR	R1,[R0]
	ANDS	R1,R1,#ZMIGA
	MOVEQ	R4,#0
	MOV	R0,#0x80	@set DDRAM address - zacetek prve vrstice
	BL	UKAZ
	MOV	R2,#16
IZPIS1:	LDRB	R0,[R3],#1
	SUBS	R4,R4,#1
	MOVEQ	R0,#0x00
	BL	ZNAK
	SUBS	R2,R2,#1
	BNE	IZPIS1
	MOV	R0,#0xC0	@set DDRAM address - zacetek druge vrstice
	BL	UKAZ
	MOV	R2,#16
IZPIS2:	LDRB	R0,[R3],#1
	SUBS	R4,R4,#1
	MOVEQ	R0,#0x00
	BL	ZNAK
	SUBS	R2,R2,#1
	BNE	IZPIS2
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Preberi ukaz s tipk *** (R0-4)
TIPKE:	LDR	R0,=0x3FFFC036	@FIO1PIN2 precita tipke v R1
	LDRB	R1,[R0]
	AND	R1,R1,#0x0F
	LDR	R0,=TIPKES	@stara vrednost tipk v R2
	LDR	R2,[R0]
	STR	R1,[R0]
	EOR	R1,R1,#0x0F
	AND	R2,R2,R1	@veljavne zastavice v R2
	LDR	R0,=UTRIP	@sahovnica ali znak?
	LDR	R3,[R0]
	LDR	R1,=KAZALO	@KAZALO	LEVO/DESNO
	LDR	R4,[R1]
	TST	R2,#0x08	@ukaz LEVO in sahovnica?
	MOVNE	R3,#ZMIGA
	SUBNE	R4,R4,#1
	TST	R2,#0x01	@ukaz DESNO in sahovnica?
	MOVNE	R3,#ZMIGA
	ADDNE	R4,R4,#1
	STR	R4,[R1]		@shrani KAZALO
	MOV	R4,#0
	TST	R2,#0x04	@ukaz GOR in znak?
	ADDNE	R4,R4,#1
	MOVNE	R3,#0
	TST	R2,#0x02	@ukaz DOL in znak?
	SUBNE	R4,R4,#1
	MOVNE	R3,#0
	LDR	R1,=PREMIK	@shrani PREMIK
	STR	R4,[R1]
	STR	R3,[R0]		@shrani sahovnico/znak
	MOV	PC,LR
.ltorg

@*** Izvedi ukaz s tipk *** (R0-)
IZVEDI:	LDR	R3,=ZNACKA	@ZNACKA=0 je ni v [R3]
	MOV	R0,#0
	STR	R0,[R3]
	LDR	R1,=KAZALO	@preveri KAZALO
	LDR	R4,[R1]
	MOVS	R4,R4
	MOVMI	R4,#0
	CMP	R4,#14
	MOVCS	R4,#14
	STR	R4,[R1]		@KAZALO v R4
	LDR	R0,=PREMIK	@PREMIK v R1
	LDR	R1,[R0]
	MOVS	R4,R4		@nastavljanje SPOMIN?
	BNE	IZVED1
	LDR	R2,=SPOMIN
	LDR	R0,[R2]
	ADD	R0,R0,R1
	MOVS	R0,R0		@preveri SPOMIN
	MOVMI	R0,#0
	CMP	R0,#9
	MOVCS	R0,#9
	STR	R0,[R2]
	MOV	PC,LR
IZVED1:	LDR	R2,=SPOMIN	@naslov nastavitev SPOMIN v R2
	LDR	R0,[R2]
	LDR	R2,=POMNIL
	ADD	R2,R2,R0,LSL#4
	SUBS	R4,R4,#8	@nastavitev frekvence?
	BPL	IZVED4
	ADD	R0,R4,#13	@nastavi ZNACKA [R3]
	CMP	R0,#10
	ADDCS	R0,R0,#1	@preskok decimalne pike
	STR	R0,[R3]
IZVED2:	ADDS	R4,R4,#1
	BEQ	IZVED3
	ADD	R1,R1,R1,LSL#2	@pomnozi PREMIK z 10
	ADD	R1,R1,R1
	B	IZVED2
IZVED3:	LDR	R0,[R2]		@popravek frekvence
	ADD	R0,R0,R1
	STR	R0,[R2]
	MOV	PC,LR
IZVED4:	SUBS	R4,R4,#2	@nastavitev jakosti?
	BPL	IZVED5
	ADD	R0,R4,#19	@nastavi ZNACKA [R3]
	STR	R0,[R3]
	ADDS	R4,R4,#1
	ADDNE	R1,R1,R1,LSL#2	@pomnozi PREMIK z 10
	ADDNE	R1,R1,R1
	LDR	R0,[R2,#4]	@popravek jakosti
	ADD	R0,R0,R1
	STR	R0,[R2,#4]
	MOV	PC,LR
IZVED5:	SUBS	R4,R4,#5	@nastavitev modulacije?
	BPL	IZVED8
	ADD	R0,R4,#31	@nastavi ZNACKA [R3]
	STR	R0,[R3]
IZVED6:	ADDS	R4,R4,#1
	BEQ	IZVED7
	ADD	R1,R1,R1,LSL#2	@pomnozi PREMIK z 10
	ADD	R1,R1,R1
	B	IZVED6
IZVED7:	LDR	R0,[R2,#8]	@popravek modulacije
	ADD	R0,R0,R1
	STR	R0,[R2,#8]
	MOV	PC,LR
IZVED8: MOV	PC,LR		@neuporabljeno!!!!!!!!!!!!!!!!!!!!
.ltorg

@*** Izpisi menu na zaslon *** (R0-5)
MENU:	STR	LR,[SP,#-4]!	@resi link
	LDR	R4,=ZASLON
	LDR	R1,=SPOMIN	@naslov nastavitev v R5
	LDR	R0,[R1]
	LDR	R1,=POMNIL
	ADD	R5,R1,R0,LSL#4
	ADD	R0,R0,#'0'	@izpisi SPOMIN
	STRB	R0,[R4],#1
	MOV	R0,#' '		@presledek
	STRB	R0,[R4],#1
	LDR	R1,=0x3FFFC015	@FIO0PIN1 uklenitev PLL?
	LDRB	R0,[R1]
	TST	R0,#8
	MOVEQ	R0,#1		@crnikriz
	MOVNE	R0,#2		@diamant
	STRB	R0,[R4],#1
	MOV	R0,#' '		@ dva presledka
	STRB	R0,[R4],#1
	STRB	R0,[R4],#1
	LDR	R3,[R5]		@izpisi frekvenco XXXX.XXX(MHz)
	ADD	R4,R4,#8
	MOV	R0,#10		@enice kHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@desetice kHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@stotice kHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#'.'		@pika
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@enice MHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@desetice MHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@stotice MHz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	ADD	R0,R3,#'0'	@tisocice MHz
	STRB	R0,[R4,#-1]!
	MOV	R1,#3		@brisi max 3 vodilne nicle
	MOV	R2,#0
MENU1:	LDRB	R0,[R4]
	ADD	R0,R0,R2
	CMP	R0,#'0'
	MOVEQ	R0,#' '
	MOVNE	R2,#256
	STRB	R0,[R4],#1
	SUBS	R1,R1,#1
	BNE	MENU1
	ADD	R4,R4,#5
	MOV	R0,#'M'		@'MHz'
	STRB	R0,[R4],#1
	MOV	R0,#'H'
	STRB	R0,[R4],#1
	MOV	R0,#'z'
	STRB	R0,[R4],#1
	LDR	R3,[R5,#4]	@izpisi jakost XX(dB)
	ADD	R4,R4,#2
	MOV	R0,#10		@enice dB
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!	
	ADD	R0,R3,#'0'	@desetice dB
	CMP	R0,#'0'		@brisi vodilno niclo
	MOVEQ	R0,#' '
	STRB	R0,[R4,#-1]!
	ADD	R4,R4,#2
	MOV	R0,#'d'		@'dB' in 5 presledkov
	STRB	R0,[R4],#1
	MOV	R0,#'B'
	STRB	R0,[R4],#1
	MOV	R0,#' '
	STRB	R0,[R4],#1
	STRB	R0,[R4],#1
	STRB	R0,[R4],#1
	STRB	R0,[R4],#1
	STRB	R0,[R4],#1
	LDR	R3,[R5,#8]	@izpisi modulacijo XXXXX(Hz)
	ADD	R4,R4,#5
	MOV	R0,#10		@enice Hz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@desetice Hz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@stotice Hz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	MOV	R0,#10		@tisocice Hz
	BL	NDELI	
	ADD	R0,R0,#'0'
	STRB	R0,[R4,#-1]!
	ADD	R0,R3,#'0'	@desettisocice kHz
	STRB	R0,[R4,#-1]!
	MOV	R1,#4		@brisi max 4 vodilne nicle
	MOV	R2,#0
MENU2:	LDRB	R0,[R4]
	ADD	R0,R0,R2
	CMP	R0,#'0'
	MOVEQ	R0,#' '
	MOVNE	R2,#256
	STRB	R0,[R4],#1
	SUBS	R1,R1,#1
	BNE	MENU2
	ADD	R4,R4,#1
	MOV	R0,#'H'		@'Hz'
	STRB	R0,[R4],#1
	MOV	R0,#'z'
	STRB	R0,[R4],#1
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Konec delovanja zbirnika Gnu ***
.end