@*** PulzniSprejemnik - S53MV 26.04.2017 ***

@*** Konstante mikrokrmilnika LPC2138/01 ***
.equ	KVARC,14745600		@frekvenca kristala (Hz)
.equ	CLK,KVARC*4		@frekvenca jedra ARM (PLL)
.equ	PCLK,CLK		@frekvenca vhodno/izhodnih enot (APBDIV)
.equ	BAUD,PCLK/16/230400	@modulo deljenja UART za 230400bps*16
.equ	N1US,CLK/3000000	@konstanta cakanja T1US za HD44780
.equ	NTIMER,CLK/38400	@nastavi frekvenco prekinitev 38400Hz

@*** Vhodno/izhodni prikljucki LPC2138/01 ***
@/RESET - vhod vezan na /ERROR.LP2951 in na /DTR.FT231XS
@P0.0/TXD0/PWM1 - izhod vezan na RXD.FT231XS 
@P0.1/RXD0/PWM3/EINT0 - vhod vezan na TXD.FT231XS
@P0.2.od/SCL0/CAP0.0 -
@P0.3.od/SDA0/MAT0.0/EINT1 -
@P0.4/SCK0/CAP0.1/AD0.6 -
@P0.5/MISO0/MAT0.1/AD0.7 -
@P0.6/MOSI0/CAP0.2/AD1.0 -
@P0.7/SSEL0/PWM2/EINT2 -
@P0.8/TXD1/PWM4/AD1.1 -
@P0.9/RXD1/PWM6/EINT3 -
@P0.10/RTS1/CAP1.0/AD1.2 -
@P0.11.od/CTS1/CAP1.1/SCL1 -
@P0.12/DSR1/MAT1.0/AD1.3 -
@P0.13/DTR1/MAT1.1/AD1.4 -
@P0.14.od/DCD1/EINT1/SDA1/BOOTLOADER(!) - vhod vezan na /RTS.FT231XS 
@P0.15/RI1/EINT2/AD1.5 -
@P0.16-23 - digitalni izhodi za LCD D0-7.HD44780
@P0.24 - ne obstaja ***
@P0.25/AD0.4/AOUT - analogni vhod
@P0.26/AD0.5 - analogni vhod
@P0.27/AD0.0/CAP0.1/MAT0.1 - analogni vhod
@P0.28/AD0.1/CAP0.2/MAT0.2 - analogni vhod
@P0.29/AD0.2/CAP0.3/MAT0.3 - analogni vhod
@P0.30/AD0.3/EINT3/CAP0.0 - analogni vhod
@P0.31(!) - nepovezan ***
@P1.0-15 - ne obstajajo ***
@P1.16-19 - vhodi z vgrajenim PULL-UP za tipke na maso
@P1.20(!) - nepovezan ***
@P1.21 - digitalni izhod za LCD RS.HD44780
@P1.22-25 - nepovezani ***
@P1.26(!) - nepovezan ***
@P1.27-29 - nepovezani ***
@P1.30 - digitalni izhod za LCD E.HD44780
@P1.31 - nepovezan ***

@*** Dodelitev pomnilnika RAM ***
.equ	SKLAD,0x40000100	@sklad raste navzdol -256byte

@*** Ukazi za delovanje zbirnika Gnu ***
.text
.arm

@*** Tabela izjem na zacetnem naslovu 0 ***
IZJEME:	B	ZACNI	@RESET
	B	IZJEME	@Undef
	B	IZJEME	@SWI
	B	IZJEME	@PAbt
	B	IZJEME	@DAbt
	NOP		@Reserved Vector
	B	IZJEME	@IRQ
@*** Prekinitev FIQ *** (R7,R8-10.FIQ)
	LDR	R8,=0xE0034000	@precitaj in pristej 6 vhodov AD0
	LDR	R9,[R8,#0x10]	@ADDR0
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	LDR	R9,[R8,#0x14]	@ADDR1
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	LDR	R9,[R8,#0x18]	@ADDR2
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	LDR	R9,[R8,#0x1C]	@ADDR3
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	LDR	R9,[R8,#0x20]	@ADDR4
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	LDR	R9,[R8,#0x24]	@ADDR5
	MOV	R9,R9,LSL#16
	ADD	R10,R10,R9,LSR#22
	ADD	R10,R10,#0x40000000	@stej stiri cikle
	TST	R10,#0xC0000000
	BNE	FIQ1	
	MOV	R7,R10,LSL#16	@shrani rezultat v R7 (skupni z glavno zanko)
	LDR	R8,=0xE000C000	@U0THR poslji rezultat na UART0
	MOV	R9,#33
	ADD	R9,R9,R10,LSR#7
	STRB	R9,[R8]
	ORR	R7,R7,R9	@dodaj znak v R7 (skupni z glavno zanko)
	MOV	R10,#0		@resetiraj akumulator
FIQ1:	LDR	R8,=0xE0004000	@T0IR=0xFF reset zahtev TIMER0
	MOV	R9,#-1
	STRB	R9,[R8]
	SUBS	PC,LR,#4	@izhod iz prekinitve FIQ
.ltorg

@*** Pocisti pomnilnik do nevarne lokacije 0x000001FC ***
.balign	512,0

@*** Vkljuci prekinitve FIQ *** (R0-4)
FIQON:	MRS	R0,CPSR		@preberi CPSR
	BIC	R0,R0,#0x40	@vkljuci prekinitve FIQ
	MSR	CPSR_c,R0	@popravi CPSR
	MOV	PC,LR
.ltorg

@*** Nastavi prekinitve TIMER0 *** (R0-1)
TIMER0:	LDR	R0,=0xE0004018	@T0MR0=NTIMER-1
	LDR	R1,=NTIMER
	SUB	R1,R1,#1
	STR	R1,[R0]
	LDR	R0,=0xE0004014	@T0MCR=0x0003 reset in int iz MR0
	MOV	R1,#0x0003
	STR	R1,[R0]
	LDR	R0,=0xE0004004	@T0TCR=0x01 vklop TIMER0
	MOV	R1,#0x01
	STR	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj VIC *** (R0-1)
VIC:	LDR	R0,=0xFFFFF00C	@VICIntSelect=0x00000010 TIMER0=FIQ
	LDR	R1,=0x00000010
	STR	R1,[R0]
	LDR	R0,=0xFFFFF010	@VICIntEnable=0x00000010 TIMER0
	LDR	R1,=0x00000010
	STR	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj MAM *** (R0-1)
MAM:	LDR	R0,=0xE01FC000	@MAMCR=0
	MOV	R1,#0
	STRB	R1,[R0]
	LDR	R0,=0xE01FC004	@MAMTIM=3
	MOV	R1,#3
	STRB	R1,[R0]
	LDR	R0,=0xE01FC000	@MAMCR=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Nastavi PCONP in APBDIV *** (R0-1)
PWRCLK:	LDR	R0,=0xE01FC0C4	@PCONP
	LDR	R1,=0x0000100A	@AD0,UART0,TIM0
	STR	R1,[R0]
	LDR	R0,=0xE01FC100	@APBDIV=1
	MOV	R1,#1
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj PLL *** (R0-2)
PLL:	LDR	R0,=0xE01FC084	@PLLCFG=0x24 P=2,M-1=3
	MOV	R1,#0x23
	STRB	R1,[R0]
	LDR	R0,=0xE01FC080	@PLLCON=0x01 PLL-enable
	MOV	R1,#0x01
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	@PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
PLL1:	LDR	R0,=0xE01FC088	@PLLSTAT cakanje uklenitve
	LDR	R1,[R0]
	ANDS	R1,R1,#0x400
	BEQ	PLL1
	LDR	R0,=0xE01FC080	@PLLCON=0x03 PLL-enable&connect
	MOV	R1,#0x03
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	@PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj GPIO *** (R0-1)
GPIO:	LDR	R0,=0xE002C000	@PINSEL0 P0.0-1=UART0
	LDR	R1,=0x00000005
	STR	R1,[R0]
	LDR	R0,=0xE002C004	@PINSEL1 P0.25-30=AD0.0-5
	LDR	R1,=0x15540000
	STR	R1,[R0]
	LDR	R0,=0xE002C014	@PINSEL2 izklop JTAG&TRACE
	LDR	R1,[R0]
	BIC	R1,R1,#0x0C
	STR	R1,[R0]
	LDR	R0,=0xE01FC1A0	@SCS=0x03 high-speed GPIO 0&1
	MOV	R1,#0x03
	STR	R1,[R0]
	LDR	R0,=0x3FFFC014	@FIO0PIN vsi 0
	MOV	R1,#0
	STR	R1,[R0]
	LDR	R0,=0x3FFFC034	@FIO1PIN vsi 0
	MOV	R1,#0
	STR	R1,[R0]
	LDR	R0,=0x3FFFC000	@FIO0DIR izhodi 0.0-0.31
	LDR	R1,=0xFFFFFFFF
	STR	R1,[R0]
	LDR	R0,=0x3FFFC020	@FIO1DIR izhodi 1.20-1.31
	LDR	R1,=0xFFF00000
	STR	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj UART0 *** (R0-1)
UART0:	LDR	R0,=0xE000C00C	@U0LCR=0x83 DLAB=1,no-parity,1stop,8bit
	MOV	R1,#0x83
	STRB	R1,[R0]
	LDR	R0,=0xE000C000	@U0DLL 
	LDR	R1,=BAUD
	STRB	R1,[R0]
	LDR	R0,=0xE000C004	@U0DLM
	MOV	R1,R1,LSR#8
	STRB	R1,[R0]
	LDR	R0,=0xE000C008	@U0FCR=0xC1 RXtrig=14bit,FIFOenable
	MOV	R1,#0xC1
	STRB	R1,[R0]
	LDR	R0,=0xE000C00C	@U0LCR=0x03 DLAB=0,no-parity,1stop,8bit
	MOV	R1,#0x03
	STRB	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj AD0.0-5 BURST *** (R0-1)
AD0:	LDR	R0,=0xE0034000	@AD0CR
	LDR	R1,=0x00210C3F	@EDGE=0,START=000,PDN=1,CLKS=000,BURST=1,CLKDIV=0x0C,SEL=0x3F
	STR	R1,[R0]
	MOV	PC,LR
.ltorg

@*** Inicializiraj HD44780 5X7,2vrstici,CGRAM *** (R0-3)
INILCD:	STR	LR,[SP,#-4]!	@resi link
	BL	T100MS		@zakasnitev 100ms
	MOV	R0,#0x38	@function set 
	BL	UKAZ
	BL	T4MS		@zakasnitev 4ms
	MOV	R0,#0x38	@function set
	BL	UKAZ
	MOV	R0,#0x38	@function set
	BL	UKAZ
	MOV	R0,#0x08	@display off
	BL	UKAZ
	MOV	R0,#0x01	@display clear
	BL	UKAZ
	BL	T4MS		@zakasnitev 4ms
	MOV	R0,#0x06	@entry mode set
	BL	UKAZ
	MOV	R0,#0x0C	@display on
	BL	UKAZ
	MOV	R0,#0x40	@set CGRAM address
	BL	UKAZ
	MOV	R2,#64		@prepisi 8 znake = 64 bajtov
	LDR	R3,=INILCD2
INILCD1:
	LDRB	R0,[R3],#1
	BL	ZNAK
	SUBS	R2,R2,#1
	BNE	INILCD1
	MOV	R0,#0x80	@set DDRAM address zacetek prve vrstice
	BL	UKAZ
	LDR	PC,[SP],#4	@povratek na link
.ltorg
INILCD2:
.byte	0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x04	@0=praznina
.byte	0x10,0x10,0x10,0x10,0x10,0x10,0x00,0x04	@1=enacrtica
.byte	0x14,0x14,0x14,0x14,0x14,0x14,0x00,0x04	@2=dvecrtici
.byte	0x15,0x15,0x15,0x15,0x15,0x15,0x00,0x04	@3=tricrtice
.byte	0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x1F	@0=praznina podcrtana
.byte	0x10,0x10,0x10,0x10,0x10,0x10,0x00,0x1F	@1=enacrtica podcrtana
.byte	0x14,0x14,0x14,0x14,0x14,0x14,0x00,0x1F	@2=dvecrtici podcrtana
.byte	0x15,0x15,0x15,0x15,0x15,0x15,0x00,0x1F	@3=tricrtice podcrtana
.align

@*** Podcrtan stolpec v desno v drugi vrstici iz R3 *** (R0-3)
STOLP:	STR	LR,[SP,#-4]!	@resi link
	MOV	R0,#0xC0	@set DDRAM address druga vrstica
	BL	UKAZ
	MOV	R2,#0
STOLP1:	MOV	R0,#0		@praznina za velike korake po 16
	CMP	R3,#16		@ena crtica?
	MOVCS	R0,#1
	CMP	R3,#32		@dve crtici?
	MOVCS	R0,#2
	CMP	R3,#48		@tri crtice?
	MOVCS	R0,#3
	AND	R1,R3,#15	@podcrtaj pripadajoci znak za male korake po 1
	CMP	R1,R2
	ADDEQ	R0,R0,#4
	BL	ZNAK		@izpisi crtice
	SUBS	R3,R3,#48	@odstej 3 crtice, negativno ustavi?
	ANDMI	R3,R3,#15
	ADD	R2,R2,#1	@zanka 16 znakov
	CMP	R2,#16
	BMI	STOLP1
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Znak iz R0 v HD44780 *** (R0-1)
ZNAK:	STR	LR,[SP,#-4]!	@resi link
	LDR	R1,=0x3FFFC016	@FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03A	@FIO1SET2
	MOV	R0,#0x20	@RS=1
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03B	@FIO1SET3
	MOV	R0,#0x40	@vklopi E
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03F	@FIO1CLR3
	MOV	R0,#0x40	@izklopi E
	STRB	R0,[R1]
	BL	T100US		@zakasnitev 100us
	LDR	PC,[SP],#4	@povratek na link
.ltorg

@*** Ukaz iz R0 v HD44780 *** (R0-1)
UKAZ:	STR	LR,[SP,#-4]!	@resi link
	LDR	R1,=0x3FFFC016	@FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03E	@FIO1CLR2
	MOV	R0,#0x20	@RS=0
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03B	@FIO1SET3
	MOV	R0,#0x40	@vklopi E
	STRB	R0,[R1]
	BL	T1US		@zakasnitev 1us
	LDR	R1,=0x3FFFC03F	@FIO1CLR3
	MOV	R0,#0x40	@izklopi E
	STRB	R0,[R1]
	BL	T100US		@zakasnitev 100us
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 1us *** (R0)
.balign	16,0
T1US:	MOV	R0,#N1US
T1US1:	SUBS	R0,R0,#1
	BPL	T1US1
	MOV	PC,LR

@*** Zakasnitev 100us *** (R0-1)
T100US:	STR	LR,[SP,#-4]!	@resi link
	MOV	R1,#100
T100US1:
	BL	T1US
	SUBS	R1,R1,#1
	BPL	T100US1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 4ms *** (R0-2)
T4MS:	STR	LR,[SP,#-4]!	@resi link
	MOV	R2,#40
T4MS1:	BL	T100US
	SUBS	R2,R2,#1
	BPL	T4MS1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 100ms *** (R0-3)
T100MS:	STR	LR,[SP,#-4]!	@resi link
	MOV	R3,#25
T100MS1:
	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T100MS1
	LDR	PC,[SP],#4	@povratek na link

@*** Zakasnitev 1s *** (R0-3)
T1S:	STR	LR,[SP,#-4]!	@resi link
	MOV	R3,#250
T1S1:	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T1S1
	LDR	PC,[SP],#4	@povratek na link

@*** Nepredznaceno deljenje R3/R0=R3, ostanek v R0 *** (R0-3)
NDELI:	MOVS	R1,R0		@prepreci deljenje z 0?
	MOVEQ	PC,LR
	MOV	R2,#1
	BMI	NDELI2
NDELI1:	MOV	R2,R2,LSL#1	@enica delitelja v MSB
	MOVS	R1,R1,LSL#1
	BPL	NDELI1
NDELI2:	MOV	R0,R3		@ostanek v R0
	MOV	R3,#0		@kvocient v R3
NDELI3:	CMP	R0,R1
	SUBCS	R0,R0,R1
	ADDCS	R3,R3,R2
	MOV	R1,R1,LSR#1
	MOVS	R2,R2,LSR#1
	BNE	NDELI3
	MOV	PC,LR

@*** Zacetek programa po resetu ***
ZACNI:	LDR	SP,=SKLAD	@inicializiraj SP
	BL	MAM	@inicializiraj MAM
	BL	PWRCLK	@nastavi PCONP in APBDIV
	BL	PLL	@inicializiraj PLL
	BL	GPIO	@inicializiraj GPIO in DAC
	BL	UART0	@inicializiraj UART0
	BL	AD0	@inicializiraj AD0 BURST,0-5
	BL	TIMER0	@nastavi prekinitve TIMER0
	BL	VIC	@inicializiraj VIC
	BL	INILCD	@inicializiraj HD44780 5X7,2vrstici,CGRAM
	MOV	R0,#0x80	@prva vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI5
ZACNI1:	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI2
	BL	ZNAK
	B	ZACNI1
ZACNI2:	MOV	R0,#0xC0	@druga vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI6
ZACNI3:	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI4
	BL	ZNAK
	B	ZACNI3
ZACNI4:	BL	T1S		@zakasnitev 1s
	BL	FIQON		@vkljuci prekinitve FIQ
	B	ZANKA	@glavna zanka programa
.ltorg
ZACNI5:	.asciz	"PulzniSprejemnik"
ZACNI6:	.asciz	"S53MV 26.04.2017"
.align

@*** Glavna zanka programa ***
ZANKA:	MOV	R0,#0x80	@nastavi polozaj v prvo vrstico
	BL	UKAZ
	MOV	R0,#'A'		@"A="
	BL	ZNAK
	MOV	R0,#'='
	BL	ZNAK
	MOV	R3,R7,LSR#16	@rezultat A/D v petmestno desetisko obliko
	MOV	R0,#10
	BL	NDELI
	MOV	R4,R0
	MOV	R0,#10
	BL	NDELI
	MOV	R5,R0	
	MOV	R0,#10
	BL	NDELI
	MOV	R6,R0
	MOV	R0,#10
	BL	NDELI
	MOV	R2,R0
	ADD	R0,R3,#'0'	@izpisi petmestni rezultat A/D
	BL	ZNAK
	ADD	R0,R2,#'0'
	BL	ZNAK
	ADD	R0,R6,#'0'
	BL	ZNAK
	ADD	R0,R5,#'0'
	BL	ZNAK
	ADD	R0,R4,#'0'
	BL	ZNAK
	MOV	R0,#' '		@" ZN="
	BL	ZNAK
	MOV	R0,#'Z'
	BL	ZNAK
	MOV	R0,#'N'
	BL	ZNAK
	MOV	R0,#'='
	BL	ZNAK
	AND	R3,R7,#0xFF	@znak v trimestno desetiško obliko
	MOV	R0,#10
	BL	NDELI
	MOV	R4,R0
	MOV	R0,#10
	BL	NDELI
	MOV	R5,R0
	ADD	R0,R3,#'0'	@izpisi trimestno stevilo znaka
	BL	ZNAK
	ADD	R0,R5,#'0'
	BL	ZNAK
	ADD	R0,R4,#'0'
	BL	ZNAK
	MOV	R0,#'=' 	@"="
	BL	ZNAK
	AND	R0,R7,#0xFF	@izpisi kot ASCII znak
	BL	ZNAK
	MOV	R3,R7,LSR#21	@rastoci stolpec v drugo vrstico
	BL	STOLP
	BL	T100MS		@zakasnitev 100ms
	B	ZANKA
.ltorg

@*** Konec delovanja zbirnika Gnu ***
.end