;*** Konstante mikrokrmilnika LPC2138/01 ***
KVARC	EQU	14745600	;frekvenca kristala (Hz)
CLK	EQU	KVARC*4		;frekvenca jedra ARM (PLL)
PCLK	EQU	CLK/2		;frekvenca vhodno/izhodnih enot (APBDIV)
BAUD	EQU	PCLK/153600	;modulo deljenja UART za 9600bps*16
N1US	EQU	CLK/3000000	;konstanta cakanja T1US za HD44780

;*** Vhodno/izhodni prikljucki LPC2138/01 ***
;/RESET - vhod vezan na /ERROR.LP2951 in na /DTR.FT231XS
;P0.0/TXD0/PWM1 - izhod vezan na RXD.FT231XS 
;P0.1/RXD0/PWM3/EINT0 - vhod vezan na TXD.FT231XS
;P0.2.od/SCL0/CAP0.0 -
;P0.3.od/SDA0/MAT0.0/EINT1 -
;P0.4/SCK0/CAP0.1/AD0.6 -
;P0.5/MISO0/MAT0.1/AD0.7 -
;P0.6/MOSI0/CAP0.2/AD1.0 -
;P0.7/SSEL0/PWM2/EINT2 -
;P0.8/TXD1/PWM4/AD1.1 -	rdeca LED
;P0.9/RXD1/PWM6/EINT3 -
;P0.10/RTS1/CAP1.0/AD1.2 - rumena LED
;P0.11.od/CTS1/CAP1.1/SCL1 -
;P0.12/DSR1/MAT1.0/AD1.3 -
;P0.13/DTR1/MAT1.1/AD1.4 - zelena LED
;P0.14.od/DCD1/EINT1/SDA1/BOOTLOADER(!) - vhod vezan na /RTS.FT231XS 
;P0.15/RI1/EINT2/AD1.5 -
;P0.16-23 - digitalni izhodi za LCD D0-7.HD44780
;P0.24 - ne obstaja ***
;P0.25/AD0.4/AOUT -
;P0.26/AD0.5 -	vhod vezan na potenciometer
;P0.27/AD0.0/CAP0.1/MAT0.1 -
;P0.28/AD0.1/CAP0.2/MAT0.2 -
;P0.29/AD0.2/CAP0.3/MAT0.3 -
;P0.30/AD0.3/EINT3/CAP0.0 -
;P0.31(!) - nepovezan ***
;P1.0-15 - ne obstajajo ***
;P1.16-19 - vhodi z vgrajenim PULL-UP za tipke na maso
;P1.20(!) - nepovezan ***
;P1.21 - digitalni izhod za LCD RS.HD44780
;P1.22-25 - nepovezani ***
;P1.26(!) - nepovezan ***
;P1.27-29 - nepovezani ***
;P1.30 - digitalni izhod za LCD E.HD44780
;P1.31 - nepovezan ***

;*** Dodelitev pomnilnika RAM ***
SKLAD	EQU	0x40000100	;sklad raste navzdol -256byte

;*** Ukazi za delovanje zbirnika ARM ***
	AREA	RESET, CODE, READONLY, ALIGN=9
	ENTRY
	CODE32

;*** Tabela izjem na zacetnem naslovu 0 ***
IZJEME	B	ZACNI	;RESET
	B	IZJEME	;Undef
	B	IZJEME	;SWI
	B	IZJEME	;PAbt
	B	IZJEME	;DAbt
	NOP		;Reserved Vector
	B	IZJEME	;IRQ
	B	IZJEME	;FIQ

;*** Onemogoci zascito vsebine FLASH na naslovu 0x000001FC ***
	ALIGN	512

;*** Inicializiraj MAM *** (R0-1)
MAM	LDR	R0,=0xE01FC000	;MAMCR=0
	MOV	R1,#0
	STRB	R1,[R0]
	LDR	R0,=0xE01FC004	;MAMTIM=3
	MOV	R1,#3
	STRB	R1,[R0]
	LDR	R0,=0xE01FC000	;MAMCR=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Nastavi PCONP in APBDIV *** (R0-1)
PWRCLK	LDR	R0,=0xE01FC100	;APBDIV=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj PLL *** (R0-2)
PLL	LDR	R0,=0xE01FC084	;PLLCFG=0x24 P=2,M-1=3
	MOV	R1,#0x23
	STRB	R1,[R0]
	LDR	R0,=0xE01FC080	;PLLCON=0x01 PLL-enable
	MOV	R1,#0x01
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	;PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
PLL1	LDR	R0,=0xE01FC088	;PLLSTAT cakanje uklenitve
	LDR	R1,[R0]
	ANDS	R1,R1,#0x400
	BEQ	PLL1
	LDR	R0,=0xE01FC080	;PLLCON=0x03 PLL-enable&connect
	MOV	R1,#0x03
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	;PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj GPIO in DAC *** (R0-1)
GPIO	LDR	R0,=0xE002C000	;PINSEL0 P0.0-1=UART0
	LDR	R1,=0x00000005
	STR	R1,[R0]
	LDR	R0,=0xE002C004	;P0.26=AD0.5 20.BIT V PINSEL1
	LDR	R1,=0x00100000
	STR	R1,[R0]
	LDR	R0,=0xE01FC1A0	;SCS=0x03 high-speed GPIO 0&1
	MOV	R1,#0x03
	STR	R1,[R0]
	LDR	R0,=0x3FFFC000	;FIO0DIR izhodi 0.0-0.31
	LDR	R1,=0xFFFFFFFF
	STR	R1,[R0]
	LDR	R0,=0x3FFFC020	;FIO1DIR izhodi 1.20-1.31
	LDR	R1,=0xFFF00000
	STR	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj UART0 *** (R0-1)
UART0	LDR	R0,=0xE000C00C	;U0LCR=0x83 DLAB=1,no-parity,1stop,8bit
	MOV	R1,#0x83
	STRB	R1,[R0]
	LDR	R0,=0xE000C000	;U0DLL 
	LDR	R1,=BAUD
	STRB	R1,[R0]
	LDR	R0,=0xE000C004	;U0DLM
	MOV	R1,R1,LSR#8
	STRB	R1,[R0]
	LDR	R0,=0xE000C008	;U0FCR=0xC1 RXtrig=14bit,FIFOenable
	MOV	R1,#0xC1
	STRB	R1,[R0]
	LDR	R0,=0xE000C00C	;U0LCR=0x03 DLAB=0,no-parity,1stop,8bit
	MOV	R1,#0x03
	STRB	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj HD44780 5X7,2vrstici,CGRAM *** (R0-3)
INILCD	STR	LR,[SP,#-4]!	;resi link
	BL	T100MS		;zakasnitev 100ms
	MOV	R0,#0x38	;function set 
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x38	;function set
	BL	UKAZ
	MOV	R0,#0x38	;function set
	BL	UKAZ
	MOV	R0,#0x08	;display off
	BL	UKAZ
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x06	;entry mode set
	BL	UKAZ
	MOV	R0,#0x0C	;display on
	BL	UKAZ
	MOV	R0,#0x40	;set CGRAM address
	BL	UKAZ
	LDR	PC,[SP],#4	;povratek na link
	LTORG


;*** Znak iz R0 v HD44780 *** (R0-1)
ZNAK	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC016	;FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03A	;FIO1SET2
	MOV	R0,#0x20	;RS=1
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03B	;FIO1SET3
	MOV	R0,#0x40	;vklopi E
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03F	;FIO1CLR3
	MOV	R0,#0x40	;izklopi E
	STRB	R0,[R1]
	BL	T100US		;zakasnitev 100us
	LDR	PC,[SP],#4	;povratek na link
	LTORG

;*** Ukaz iz R0 v HD44780 *** (R0-1)
UKAZ	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC016	;FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03E	;FIO1CLR2
	MOV	R0,#0x20	;RS=0
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03B	;FIO1SET3
	MOV	R0,#0x40	;vklopi E
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03F	;FIO1CLR3
	MOV	R0,#0x40	;izklopi E
	STRB	R0,[R1]
	BL	T100US		;zakasnitev 100us
	LDR	PC,[SP],#4	;povratek na link

;*** AD PRETVORNIK *** (R0-1 IN R5)

ADC	STR	LR,[SP,#-4]!	;resi link
	LDR	R0,=0xE0034000	;AD0CR
	LDR	R1,=0x01204020	;START=001PDN=1,CLKS=000,BURST=0,CLKDIV=0X40,NASTAVI DA JE PRIBL 4,5MHz, SEL=0X20,AD0.5
	STR	R1,[R0]		;S TEM SMO POGNALI AD PRETVORNIK
ADZ	LDR	R0,=0xE0034004	;V AD GLOBAL DATA REG, PREVERI DA JE ZAGNAN, ADOGDR
	LDR	R1,[R0]
	TST	R1,#0x80000000	;PREVERI CE DONE BIT NA 1
	BEQ	ADZ
	MOV	R1,R1,LSL#16	;RESULT BITI SO 15:6
	MOV	R5,R1,LSR#22	;POBRISEMO OSTALE BITE IN SE NASTAVIMO ENICE NA BIT 0
	LDR	PC,[SP],#4	;povratek na link
	LTORG


;*** LUCI SEMAFORJA, RDECA IN ZELENA ODVISNA OD POTENCIOMETRA NA AD0.5	***

RDECA	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC015	;FIO0PIN1 P0.8-15
	MOV	R0,#0x01	;P0.8 NA 1	
	STRB	R0,[R1]
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x80	;prva vrstica besedila
	BL	UKAZ
	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	MOV	R3,#13		;CR nova vrstica na UART0
	STRB	R3,[R1]
	MOV	R3,#10		;LF
	STRB	R3,[R1]
	LDR	R2,=RED3
RED1	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	RED2
	STRB	R0,[R1]
	BL	ZNAK		;izpis na LCD
	B	RED1
RED2	BL	ADC
	CMP	R5,#0x200
	BLPL	T3S
	BLMI	T1S
	BL	T1S
	LDR	PC,[SP],#4	;povratek na link
	LTORG
RED3	DCB	"Cakaj!",0
	ALIGN	4

RDRU	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC015	;FIO0PIN1 P0.8-15
	MOV	R0,#0x05	;P0.8 IN P0.10 NA 1	
	STRB	R0,[R1]
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x80	;prva vrstica besedila
	BL	UKAZ
	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	MOV	R3,#13		;CR nova vrstica na UART0
	STRB	R3,[R1]
	MOV	R3,#10		;LF
	STRB	R3,[R1]
	LDR	R2,=RDRU3
RDRU1	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	RDRU2
	STRB	R0,[R1]
	BL	ZNAK
	B	RDRU1
RDRU2	BL	T1S		;CAKAJ 1S
	LDR	PC,[SP],#4	;povratek na link
	LTORG
RDRU3	DCB	"Pripravi se!",0
	ALIGN	4

ZELENA	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC015	;FIO0PIN1 P0.8-15
	MOV	R0,#0x00	;P0.8 IN P0.10 NA 0	
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC015	;FIO0PIN1 P0.8-15
	MOV	R0,#0x20	;P0.13 NA 1	
	STRB	R0,[R1]
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x80	;prva vrstica besedila
	BL	UKAZ
	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	MOV	R3,#13		;CR nova vrstica na UART0
	STRB	R3,[R1]
	MOV	R3,#10		;LF
	STRB	R3,[R1]
	LDR	R2,=ZEL3
ZEL1	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZEL2
	STRB	R0,[R1]
	BL	ZNAK
	B	ZEL1
ZEL2	BL	ADC
	CMP	R5,#0x200
	BLPL	T3S
	BLMI	T1S
	BL	T1S
	LDR	PC,[SP],#4	;povratek na link
	LTORG
ZEL3	DCB	"Pelji!",0
	ALIGN	4

RUMENA	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC015	;FIO0PIN1 P0.8-15
	MOV	R0,#0x04	;P0.8 IN P0.10 NA 1	
	STRB	R0,[R1]
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x80	;prva vrstica besedila
	BL	UKAZ
	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	MOV	R3,#13		;CR nova vrstica na UART0
	STRB	R3,[R1]
	MOV	R3,#10		;LF
	STRB	R3,[R1]
	LDR	R2,=RUM3
RUM1	LDR	R1,=0xE000C000	;U0THR izpis stevca na UART0
	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	RUM2
	STRB	R0,[R1]
	BL	ZNAK
	B	RUM1
RUM2	BL	T1S		;CAKAJ 1S
	LDR	PC,[SP],#4	;povratek na link
	LTORG
RUM3	DCB	"Upocasni!",0
	ALIGN	4


;*** Zakasnitev 1us *** (R0)
	ALIGN	16
T1US	MOV	R0,#N1US
T1US1	SUBS	R0,R0,#1
	BPL	T1US1
	MOV	PC,LR

;*** Zakasnitev 100us *** (R0-1)
T100US	STR	LR,[SP,#-4]!	;resi link
	MOV	R1,#100
T100US1	BL	T1US
	SUBS	R1,R1,#1
	BPL	T100US1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 4ms *** (R0-2)
T4MS	STR	LR,[SP,#-4]!	;resi link
	MOV	R2,#40
T4MS1	BL	T100US
	SUBS	R2,R2,#1
	BPL	T4MS1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 100ms *** (R0-3)
T100MS	STR	LR,[SP,#-4]!	;resi link
	MOV	R3,#25
T100MS1	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T100MS1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 1s *** (R0-3)
T1S	STR	LR,[SP,#-4]!	;resi link
	MOV	R3,#250
T1S1	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T1S1
	LDR	PC,[SP],#4	;povratek na link

;***	Zakasnitev 3s *** (R0-4)
T3S	STR	LR,[SP,#-4]!	;resi link
	MOV	R4,#2
T3S1	BL	T1S
	SUBS	R4,R4,#1
	BPL	T3S1
	LDR	PC,[SP],#4	;povratek na link	


;*** Zacetek programa po resetu ***
ZACNI	LDR	SP,=SKLAD	;inicializiraj SP
	BL	MAM	;inicializiraj MAM
	BL	PWRCLK	;nastavi PCONP in APBDIV
	BL	PLL	;inicializiraj PLL
	BL	GPIO	;inicializiraj GPIO in DAC
	BL	UART0	;inicializiraj UART0
	BL	INILCD	;inicializiraj HD44780 5X7,2vrstici,CGRAM
	BL	T1S	;zakasnitev 1s
	B	ZANKA	;glavna zanka programa
	LTORG
	ALIGN	4


;*** Glavna zanka programa ***
ZANKA	
	BL	RDECA
	BL	RDRU
	BL 	ZELENA
	BL	RUMENA

	B	ZANKA
	LTORG

;*** Konec delovanja zbirnika ARM ***
	END