;*** Preizkus mikrokrmilnika - S53MV 23.03.2014 ***

;*** Konstante mikrokrmilnika LPC2138/01 *** ;EQU da zapišemo konstante
KVARC	EQU	14745600	;frekvenca kristala (Hz)
CLK	EQU	KVARC*4		;frekvenca jedra ARM (PLL)
PCLK	EQU	CLK/2		;frekvenca vhodno/izhodnih enot (APBDIV)
BAUD	EQU	PCLK/153600	;modulo deljenja UART za 9600bps*16
N1US	EQU	CLK/3000000	;konstanta cakanja T1US za HD44780

;*** Vhodno/izhodni prikljucki LPC2138/01 ***
;/RESET - vhod vezan na /ERROR.LP2951 in na /DTR.FT231XS
;P0.0/TXD0/PWM1 - izhod vezan na RXD.FT231XS 
;P0.1/RXD0/PWM3/EINT0 - vhod vezan na TXD.FT231XS
;P0.2.od/SCL0/CAP0.0 -
;P0.3.od/SDA0/MAT0.0/EINT1 -
;P0.4/SCK0/CAP0.1/AD0.6 -
;P0.5/MISO0/MAT0.1/AD0.7 -
;P0.6/MOSI0/CAP0.2/AD1.0 -
;P0.7/SSEL0/PWM2/EINT2 -
;P0.8/TXD1/PWM4/AD1.1 - pwm izhod
;P0.9/RXD1/PWM6/EINT3 -
;P0.10/RTS1/CAP1.0/AD1.2 -
;P0.11.od/CTS1/CAP1.1/SCL1 -
;P0.12/DSR1/MAT1.0/AD1.3 -
;P0.13/DTR1/MAT1.1/AD1.4 -
;P0.14.od/DCD1/EINT1/SDA1/BOOTLOADER(!) - vhod vezan na /RTS.FT231XS 
;P0.15/RI1/EINT2/AD1.5 -
;P0.16-23 - digitalni izhodi za LCD D0-7.HD44780
;P0.24 - ne obstaja ***
;P0.25/AD0.4/AOUT -
;P0.26/AD0.5 -                    ad vhod
;P0.27/AD0.0/CAP0.1/MAT0.1 -
;P0.28/AD0.1/CAP0.2/MAT0.2 -
;P0.29/AD0.2/CAP0.3/MAT0.3 -
;P0.30/AD0.3/EINT3/CAP0.0 -
;P0.31(!) - nepovezan ***
;P1.0-15 - ne obstajajo ***
;P1.16-19 - vhodi z vgrajenim PULL-UP za tipke na maso
;P1.20(!) - nepovezan ***
;P1.21 - digitalni izhod za LCD RS.HD44780
;P1.22-25 - nepovezani ***
;P1.26(!) - nepovezan ***
;P1.27-29 - nepovezani ***
;P1.30 - digitalni izhod za LCD E.HD44780
;P1.31 - nepovezan ***

;*** Dodelitev pomnilnika RAM ***
SKLAD	EQU	0x40000100	;rezervacija za sklad - raste navzdol -256byte

;*** Ukazi za delovanje zbirnika ARM ***
	AREA	RESET, CODE, READONLY, ALIGN=9
	ENTRY
	CODE32

;*** Tabela izjem na zacetnem naslovu 0 ***
IZJEME	B	ZACNI	;RESET
	B	IZJEME	;Undef
	B	IZJEME	;SWI
	B	IZJEME	;PAbt
	B	IZJEME	;DAbt
	NOP		;Reserved Vector
	B	IZJEME	;IRQ
	B	IZJEME	;FIQ

;*** Onemogoci zascito vsebine FLASH na naslovu 0x000001FC ***
	ALIGN	512 ;prepiši nevarno lokacijo z 0

;*** Inicializiraj MAM *** (R0-1) ;memory accelerator module: vključi predpomnilnik za flash
MAM	LDR	R0,=0xE01FC000	;MAMCR=0 pseudo ukaz LDR ('='), zbirnik to pretvori v LDR R0,[PC,#odmik ]
	MOV	R1,#0
	STRB	R1,[R0]
	LDR	R0,=0xE01FC004	;MAMTIM=3
	MOV	R1,#3
	STRB	R1,[R0]
	LDR	R0,=0xE01FC000	;MAMCR=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR ;vrnemo se tja od koder smo prišli
	LTORG ;

;*** Nastavi PCONP in APBDIV *** (R0-1) <- oznaka katere registre smo prepisali
PWRCLK	LDR	R0,=0xE01FC0C4	;PCONP
	LDR	R1,=0x00000008	;UART0
	;STR	R1,[R0] 		;deaktiviramo PWR saving
	LDR	R0,=0xE01FC100	;APBDIV=2
	MOV	R1,#2
	STRB	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj PLL *** (R0-2)
PLL	LDR	R0,=0xE01FC084	;PLLCFG=0x24 P=2,M-1=3
	MOV	R1,#0x23
	STRB	R1,[R0]
	LDR	R0,=0xE01FC080	;PLLCON=0x01 PLL-enable
	MOV	R1,#0x01
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	;PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
PLL1	LDR	R0,=0xE01FC088	;PLLSTAT cakanje uklenitve
	LDR	R1,[R0]
	ANDS	R1,R1,#0x400
	BEQ	PLL1
	LDR	R0,=0xE01FC080	;PLLCON=0x03 PLL-enable&connect
	MOV	R1,#0x03
	STRB	R1,[R0]
	LDR	R0,=0xE01FC08C	;PLLFEED
	MOV	R1,#0xAA
	MOV	R2,#0x55
	STRB	R1,[R0]
	STRB	R2,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj GPIO in DAC *** (R0-1)
GPIO	LDR	R0,=0xE002C000	;PINSEL0 P0.0-1=UART0
	LDR	R1,=0x00020005	;17:16 bit: 10 za pwm4 na p0.8
	STR	R1,[R0]
	LDR	R0,=0xE002C004	;PINSEL1 P0.25=AOUT
	LDR	R1,=0x00180000 	;da nastavimo P0.26 na ADC0.5
	STR	R1,[R0]		
	LDR	R0,=0xE002C014	;PINSEL2 izklop JTAG&TRACE
	LDR	R1,[R0] 	;nalozi vsebino R0 v R1
	BIC	R1,R1,#0x0C	; pobrisi 2. in 3. bit
	STR	R1,[R0]
	LDR	R0,=0xE01FC1A0	;SCS=0x03 high-speed GPIO 0&1
	MOV	R1,#0x03	;mov hitreje kot LDR
	STR	R1,[R0]
	LDR	R0,=0x3FFFC014	;FIO0PIN vsi 1
	MOV	R1,#-1
	STR	R1,[R0]
	LDR	R0,=0x3FFFC034	;FIO1PIN vsi 0
	MOV	R1,#0
	STR	R1,[R0]
	LDR	R0,=0x3FFFC000	;FIO0DIR izhodi 0.0-0.31
	LDR	R1,=0xFFFFFFFF
	STR	R1,[R0]
	LDR	R0,=0x3FFFC020	;FIO1DIR izhodi 1.20-1.31
	LDR	R1,=0xFFF00000
	STR	R1,[R0]
	LDR	R0,=0xE006C000	;DACR sredina skale, visok tok
	LDR	R1,=0x00008000
	STR	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj UART0 *** (R0-1)
UART0	LDR	R0,=0xE000C00C	;U0LCR=0x83 DLAB=1,no-parity,1stop,8bit
	MOV	R1,#0x83
	STRB	R1,[R0]
	LDR	R0,=0xE000C000	;U0DLL 
	LDR	R1,=BAUD
	STRB	R1,[R0]
	LDR	R0,=0xE000C004	;U0DLM
	MOV	R1,R1,LSR#8
	STRB	R1,[R0]
	LDR	R0,=0xE000C008	;U0FCR=0xC1 RXtrig=14bit,FIFOenable
	MOV	R1,#0xC1
	STRB	R1,[R0]
	LDR	R0,=0xE000C00C	;U0LCR=0x03 DLAB=0,no-parity,1stop,8bit
	MOV	R1,#0x03
	STRB	R1,[R0]
	MOV	PC,LR
	LTORG

;*** Inicializiraj HD44780 5X7,2vrstici,CGRAM *** (R0-3)
INILCD	STR	LR,[SP,#-4]!	;resi link
	BL	T100MS		;zakasnitev 100ms
	MOV	R0,#0x38	;function set 
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x38	;function set
	BL	UKAZ
	MOV	R0,#0x38	;function set
	BL	UKAZ
	MOV	R0,#0x08	;display off
	BL	UKAZ
	MOV	R0,#0x01	;display clear
	BL	UKAZ
	BL	T4MS		;zakasnitev 4ms
	MOV	R0,#0x06	;entry mode set
	BL	UKAZ
	MOV	R0,#0x0C	;display on
	BL	UKAZ
	MOV	R0,#0x40	;set CGRAM address
	BL	UKAZ
	MOV	R2,#64		;prepisi 8 znake = 64 bajtov
	LDR	R3,=INILCD2
INILCD1	LDRB	R0,[R3],#1	;zapiši v R0 vsebino R3, zashiftano za 1 vrstico
	BL	ZNAK
	SUBS	R2,R2,#1
	BNE	INILCD1
	MOV	R0,#0x80	;set DDRAM address zacetek prve vrstice
	BL	UKAZ
	LDR	PC,[SP],#4	;povratek na link
	LTORG
INILCD2	DCB	0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x04	;0=praznina
	DCB	0x10,0x10,0x10,0x10,0x10,0x10,0x00,0x04	;1=enacrtica
	DCB	0x1C,0x1C,0x1C,0x1C,0x1C,0x1C,0x00,0x04	;2=dvecrtici
	DCB	0x1F,0x1F,0x1F,0x1F,0x1F,0x1F,0x00,0x04	;3=tricrtice
	DCB	0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x1F	;0=praznina podcrtana
	DCB	0x10,0x10,0x10,0x10,0x10,0x10,0x00,0x1F	;1=enacrtica podcrtana
	DCB	0x1C,0x1C,0x1C,0x1C,0x1C,0x1C,0x00,0x1F	;2=dvecrtici podcrtana
	DCB	0x1F,0x1F,0x1F,0x1F,0x1F,0x1F,0x00,0x1F	;3=tricrtice podcrtana
	ALIGN
	
;*** nastavi PWM***
INIPWM	LDR	R0,=0xE0014018	;PWMMR0, Match 0
	LDR	R1,=0x3FF
	STR	R1,[R0]
	LDR	R0,=0xE001400C	;PWMPR, Prescaler
	MOV	R1,#0x1C
	STR	R1,[R0]
	LDR	R0,=0xE0014014	;PWMMCR, Match control
	MOV	R1,#0x02
	STR	R1,[R0]
	LDR	R0,=0xE001404C	;PWMPCR PWM 4 channel enable
	LDR	R1,=0x1000	
	STR	R1,[R0]	
	LDR	R0,=0xE0014004	;PWMTCR
	MOV	R1,#0x09
	STR	R1,[R0]
	MOV	PC,LR
	LTORG



;*** Podcrtan stolpec v desno v drugi vrstici iz R3 *** (R0-3)
STOLP	STR	LR,[SP,#-4]!	;resi link
	MOV	R0,#0xC0	;set DDRAM address druga vrstica
	BL	UKAZ
	MOV	R2,#0
STOLP1	MOV	R0,#0		;praznina za velike korake po 16
	CMP	R3,#21		;ena crtica?
	MOVCS	R0,#1
	CMP	R3,#42		;dve crtici?
	MOVCS	R0,#2
	CMP	R3,#63		;tri crtice?
	MOVCS	R0,#3
	AND	R1,R3,#15	;podcrtaj pripadajoci znak za male korake po 1, fine tuning
	CMP	R1,R2		;preveri če je R1 >= R2:0,1,2,...16
	ADDEQ	R0,R0,#4	;dodaj 4, torej znak s podčrtajem
	BL	ZNAK		;izpisi crtice
	SUBS	R3,R3,#64	;odstej 3 crtice, negativno ustavi?
	ANDMI	R3,R3,#15	;AND z 1111, če je R3 < 64, da ostaja +
	ADD	R2,R2,#1	;zanka 16 znakov
	CMP	R2,#16		
	BMI	STOLP1		;če je R2 manjši od 16, idi na STOLP1
	LDR	PC,[SP],#4	;povratek na link
	LTORG

;*** Znak iz R0 v HD44780 *** (R0-1)
ZNAK	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC016	;FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03A	;FIO1SET2
	MOV	R0,#0x20	;RS=1
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03B	;FIO1SET3
	MOV	R0,#0x40	;vklopi E
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03F	;FIO1CLR3
	MOV	R0,#0x40	;izklopi E
	STRB	R0,[R1]
	BL	T100US		;zakasnitev 100us
	LDR	PC,[SP],#4	;povratek na link
	LTORG

;*** Ukaz iz R0 v HD44780 *** (R0-1)
UKAZ	STR	LR,[SP,#-4]!	;resi link
	LDR	R1,=0x3FFFC016	;FIO0PIN2 podatek
	STRB	R0,[R1]
	LDR	R1,=0x3FFFC03E	;FIO1CLR2
	MOV	R0,#0x20	;RS=0
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03B	;FIO1SET3
	MOV	R0,#0x40	;vklopi E
	STRB	R0,[R1]
	BL	T1US		;zakasnitev 1us
	LDR	R1,=0x3FFFC03F	;FIO1CLR3
	MOV	R0,#0x40	;izklopi E
	STRB	R0,[R1]
	BL	T100US		;zakasnitev 100us
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 1us *** (R0)
	ALIGN	16
T1US	MOV	R0,#N1US
T1US1	SUBS	R0,R0,#1
	BPL	T1US1
	MOV	PC,LR

;*** Zakasnitev 100us *** (R0-1)
T100US	STR	LR,[SP,#-4]!	;resi link
	MOV	R1,#100
T100US1	BL	T1US
	SUBS	R1,R1,#1
	BPL	T100US1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 4ms *** (R0-2)
T4MS	STR	LR,[SP,#-4]!	;resi link
	MOV	R2,#40
T4MS1	BL	T100US
	SUBS	R2,R2,#1
	BPL	T4MS1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 100ms *** (R0-3)
T100MS	STR	LR,[SP,#-4]!	;resi link
	MOV	R3,#25
T100MS1	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T100MS1
	LDR	PC,[SP],#4	;povratek na link

;*** Zakasnitev 1s *** (R0-3)
T1S	STR	LR,[SP,#-4]!	;resi link
	MOV	R3,#250
T1S1	BL	T4MS
	SUBS	R3,R3,#1
	BPL	T1S1
	LDR	PC,[SP],#4	;povratek na link

;*** Zacetek programa po resetu ***
ZACNI	LDR	SP,=SKLAD	;inicializiraj SP
	BL	MAM	;inicializiraj MAM
	BL	PWRCLK	;nastavi PCONP in APBDIV
	BL	PLL	;inicializiraj PLL
	BL	GPIO	;inicializiraj GPIO in DAC
	BL	UART0	;inicializiraj UART0
	BL	INILCD	;inicializiraj HD44780 5X7,2vrstici,CGRAM
	BL	INIPWM 	;inicializiraj PWM4
	
	
	
	MOV	R0,#0x80	;prva vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI7
ZACNI1	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI2
	BL	ZNAK
	B	ZACNI1
ZACNI2	MOV	R0,#0xC0	;druga vrstica besedila
	BL	UKAZ
	LDR	R2,=ZACNI8
ZACNI3	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI4
	BL	ZNAK
	B	ZACNI3
ZACNI4	BL	T1S
	BL	T1S
	BL	T1S
	MOV	R0,#0x80	;prva vrstica
	BL	UKAZ
	LDR	R2,=ZACNI9
ZACNI5	LDRB	R0,[R2],#1
	MOVS	R0,R0
	BEQ	ZACNI6
	BL	ZNAK
	B	ZACNI5
ZACNI6	MOV	R8,#2048		;zacetni stevec zanke
	B	ZANKA	;glavna zanka programa
	LTORG
ZACNI7	DCB	" PWM & ADC TEST ",0
ZACNI8	DCB	"PWM=P0.8AD=P0.26",0
ZACNI9	DCB	"    mV Duty: __%",0
	ALIGN	4
	
;*** Nepredznaceno deljenje R3/R0=R3, ostanek v R0 *** (R0-3)
NDELI	MOVS	R1,R0		;prepreci deljenje z 0?
	MOVEQ	PC,LR
	MOV	R2,#1
	BMI	NDELI2
NDELI1	MOV	R2,R2,LSL#1	;enica delitelja v MSB
	MOVS	R1,R1,LSL#1
	BPL	NDELI1
NDELI2	MOV	R0,R3		;ostanek v R0
	MOV	R3,#0		;kvocient v R3
NDELI3	CMP	R0,R1
	SUBCS	R0,R0,R1
	ADDCS	R3,R3,R2
	MOV	R1,R1,LSR#1
	MOVS	R2,R2,LSR#1
	BNE	NDELI3
	MOV	PC,LR
	
;*** AD pretvorba ***(R0-1)


;*** Glavna zanka programa ***

ZANKA	LDR 	R0,=0xE0034000 ;AD0CR naslov
	LDR 	R1,=0x01204020	;PDN = 1, BURST = 0, CLKDIV 0x40, SEL 0x20;vsebina, ADC 5
	STR 	R1,[R0]
	
ADZANKA	LDR	R0,=0xE0034004 ;AD0GDR
	LDR 	R1,[R0]
	TST	R1,#0x80000000	;MOVS R1,R1, TST AND operacija
	BEQ	ADZANKA		;BPL ADZANKA
	
	MOV 	R1,R1,LSL#16
	MOV 	R1,R1,LSR#22
	
	LDR	R0,=0xE0014040 ;naslov match registra
	STR	R1, [R0]	;naloži ADC konverzijo iz r1 v r0
	
	LDR	R0,=0xE0014050
	MOV	R2,#0x10	;latch enable pwm4
	STR	R2,[R0]
	
	
	MOV 	R3,R1,LSL#22 
	MOV 	R3,R3,LSR#22
	MOV	R4,R3		;shrani ADC konverzijo v R4
	
	LDR	R0,=3300
	MUL	R3,R4,R0	;pomnoži ADC konverzijo s 3300mV
	LDR	R0,=1023	;deli s 1023 
	BL	NDELI
		
	;LCD prikaz stevil
	MOV 	R0, #0x83 	;enice
	BL 	UKAZ
	
	MOV	R0,#10
	BL 	NDELI
	
	ADD 	R0,R0,#"0"
	BL 	ZNAK
	
	MOV 	R0,#0x82 ;desetice
	BL 	UKAZ
	MOV 	R0,#10
	BL 	NDELI
	ADD 	R0,R0,#48 ;dodaj ostanku v R0 offset 48, ker je to kjer je 0
	BL 	ZNAK
	
	MOV 	R0, #0x81 ;stotice
	BL 	UKAZ
	MOV 	R0, #10
	BL 	NDELI
	ADD 	R0,R0,#48
	BL 	ZNAK
	
	MOV 	R0, #0x80 ;tisocice
	BL 	UKAZ	
	ADD 	R0,R3,#48
	BL 	ZNAK
	
	;izpisi duty cycle v drugo vrstico
	MOV	R3,R4		
	BL	STOLP
	
	;duty % izpis
	MOV	R3,R4	
	MOV	R0,#10
	BL	NDELI
	
	MOV	R0,#0x8E	;desetice %
	BL	UKAZ
	MOV	R0,#10
	BL	NDELI
	ADD	R0,R0,#48
	BL 	ZNAK
	
	MOV	R0,#0x8D	;stotice %
	BL	UKAZ
	ADD	R0,R3,#48
	BL	ZNAK
		
		
	BL	T100MS		;zakasnitev 100ms
	ADD	R8,R8,#1	;stevec zanke R8
	B	ZANKA
	LTORG

;*** Konec delovanja zbirnika ARM ***
	END